$! GET_ME_OFF.COM - Kill all other logins on the current node
$!
$! Author: Peter Johansson (peter@cs.umbc.edu)
$!
$! This file is intended for informational purposes only - Execute it at
$! your own risk.  All code Copyright (C) 1993 by Peter Johansson.
$!
$! Non-commercial use unrestricted so long as all attributions remain
$! intact.  That is, if you use any part or parts  of this code, I want
$! credit for my work.
$!
$! --- begin origonal file ---
$!
$! This .COM file logs out all users signed onto the account that this
$! program is run from, except the user who actually runs this program.
$!
$! This is handy if you get your terminal into an infinite loop, use
$! INUSE ][ and forget your password, or see an unauthorized user on
$! on your account.
$!
$   set noon
$   on control_y then goto done
$   privs = f$setprv("noworld,nogroup")
$   bell[0,32] = 7
$   context = ""
$   master = f$getjpi ("", "master_pid")
$ loop:
$   pid = f$pid(context)
$   if pid .eqs. "" then goto done
$   if f$getjpi (pid, "master_pid") .eqs. master then goto loop
$! Unauthorized user!
$   if f$getjpi (pid, "master_pid") .nes. pid then goto loop  !ignore subprocesses
$   write sys$output "Logging out process/name: " + f$getjpi (pid, "prcnam") + bell
$   stop/id='pid'
$   goto loop
$ done:
$ exit