$! CLEAN.COM - Delete unwanted files from a directory
$!
$! Author: Peter Johansson (peter@cs.umbc.edu)
$!
$! This file is intended for informational purposes only - Execute it at
$! your own risk.  All code Copyright (C) 1993 by Peter Johansson.
$!
$! Non-commercial use unrestricted so long as all attributions remain
$! intact.  That is, if you use any part or parts  of this code, I want
$! credit for my work.
$!
$! --- begin origonal file ---
$!
$! This program cleans up your files in all subdirectories below and including
$!    the current subdir level in your account
$!
$ default = "*.lis;* *.obj;* *.exe;* *.out;* *.log;*"
$!
$   delete = "delete"
$   purge = "purge"
$   rename = "rename"
$   set noon
$   on error then goto error
$   set control_y
$   on control_y then goto fix_system
$   save_message = f$env("message")
$   set message/nofac/noident/nosev/text
$   flist = p1
$   if flist .eqs. "" then flist = default
$   flist = f$edit (flist, "trim, compress")
$   show quota
$   write sys$output ""
$   posn = 0
$!
$ loop:
$   file_spec = f$element (posn, " ", flist)
$   if file_spec .eqs. " " then goto renumber
$   write sys$output "delete ''file_spec'"
$   if f$search (file_spec) .eqs. ""
$     then write sys$output "no files match ''file_spec'"
$     else delete 'file_spec'
$     if $severity .eq. 1
$       then write sys$output "Ok."
$       else write sys$output "Error!"
$     endif
$   endif
$   posn = posn + 1
$   goto loop
$!
$ renumber:
$   on warning then goto error
$   write sys$output f$fao ("!/Purging old revisions...!/")
$   purge
$   write sys$output f$fao ("!/Renaming files to revision level 1...!/")
$   rename/log *.*;*/exclude=*.*;1 *.*;1
$  write sys$output ""
$   show quota
$   write sys$output f$fao ("!/All Done!!!!!!!/")
$   goto fix_system
$!
$ error:
$   write sys$output ""
$   write sys$output "A serious error has occured!!!"
$   write sys$output "Now exiting command file."
$ fix_system:
$   set noon
$   set message'save_message'
$ exit