; ifint_64.asm  code ifint_64.c for nasm 
; /* ifint_64.c an 'if' statement that will be coded for nasm */
; #include <stdio.h>
; int main()
; {
;   long int a=1;
;   long int b=2;
;   long int c=3;
;   long int xyz=4;
; 
;   printf("a=%ld  b=%ld  c=%ld  xyz=%ld \n",a,b,c,xyz) 
;
;   if(a<b)
;     printf("true a < b \n");
;   else
;     printf("wrong on a < b \n");
; 
;   if(b>c)
;     printf("wrong on b > c \n");
;   else
;     printf("false b > c \n");
; 
;   if(4==xyz) goto label1e;
;   printf("failed 4==xyz \n");
;label1e: printf("passed 4==xyz \n");
; 
;   if(5>xyz) goto label1g;
;   printf("failed 5>xyz \n");
;label1g: printf("passed 5>xyz \n");
; 
;   if(3<xyz) goto label1l;
;   printf("failed 3<xyz \n");
;label1l: printf("passed 3<xyz \n");
;   return 0;
;}
; result of executing both "C" and assembly is:
; a=1  b=2  c=3  xyz=4 
; true a < b 
; false b > c 
; passed 4==xyz 
; passed 5>xyz 
; passed 3<xyz 

	
	global	main		; define for linker
        extern	printf		; tell linker we need this C function
        section .data		; Data section, initialized variables
a:	dq 1
b:	dq 2
c:	dq 3
xyz:	dq 4
fmtabcx: db "a=%ld  b=%ld  c=%ld  xyz=%ld",10,0
fmt1:   db "true a < b ",10,0
fmt2:   db "wrong on a < b ",10,0
fmt3:   db "wrong on b > c ",10,0
fmt4:   db "false b > c ",10,0
fmt5:	db "failed 4==xyz ",10,0
fmt6:	db "passed 4==xyz ",10,0
fmt7:	db "failed 5>xyz ",10,0
fmt8:	db "passed 5>xyz ",10,0
fmt9:	db "failed 3<xyz ",10,0
fmt10:	db "passed 3<xyz ",10,0
	
	section .text
main:	push	rbp		; set up stack

	mov	rdi,fmtabcx
	mov	rsi,[a]
	mov	rdx,[b]
	mov	rcx,[c]
	mov	r8,[xyz]
	mov	rax,0
	call printf

	mov	rax,[a]		; a
	cmp	rax,[b]		; compare a to b
	jge	false1		; choose jump to false part
	; a < b sign is set
        mov	rdi, fmt1	; printf("true a < b \n");
	mov	rax,0
        call    printf	
        jmp	exit1		; jump over false part
false1:	;  a < b is false 
        mov	rdi, fmt2	; printf("wrong on a < b \n");
	mov	rax,0
        call    printf
exit1:				; finished 'if' statement

	mov	rax,[b]		; b
	cmp	rax,[c]		; compare b to c
	jle	false2		; choose jump to false part
	; b > c sign is not set
        mov	rdi, fmt3	; printf("wrong on b > c \n");
	mov	rax,0
        call    printf	
        jmp	exit2		; jump over false part
false2:	;  b > c is false 
        mov	rdi, fmt4	; printf("false b > c \n");
	mov	rax,0
        call    printf
exit2:				; finished 'if' statement

	mov	rax,4
	cmp	rax,[xyz]	; if(4==xyz) goto label1e;
	je	label1e
	mov	rdi, fmt5
	mov	rax,0
	call	printf
label1e:mov	rdi, fmt6
	mov	rax,0
	call	printf

	mov	rax,5
	cmp	rax,[xyz]	; if(5>xyz) goto label1g;
	jg	label1g
	mov	rdi, fmt7
	mov	rax,0
	call	printf
label1g:mov	rdi, fmt8
	mov	rax,0
	call	printf

	mov	rax,3
	cmp	rax,[xyz]	; if(3<xyz) goto label1l;
	jl	label1l
	mov	rdi, fmt9
	mov	rax,0
	call	printf
label1l:mov	rdi, fmt10
	mov	rax,0
	call	printf

				; just show jne  not equal compiles
	jne	next
next:
	
	pop	rbp		; restore stack
	mov	rax,0		; normal, no error, return value
	ret			; return 0;