;; Metacircular evaluator adapted from adapted from chapter 4 of
;; Structure and Interpretation of Computer Programs.  Run in the R5RS
;; version of PLT Scheme since it requires mutable pairs.

(define (mceval exp env)
  (cond ((self-evaluating? exp) exp)
        ((symbol? exp) (lookup-variable-value exp env))
        ((quoted? exp) (cadr exp))
        ((assignment? exp) (eval-assignment exp env))
        ((definition? exp) (eval-definition exp env))
        ((if? exp) (eval-if exp env))
        ((lambda? exp) (make-procedure (cadr exp) (cddr exp) env))
        ((begin? exp) (eval-sequence (cdr exp) env))
        ((application? exp)
         (mcapply (mceval (car exp) env)
		  (map (lambda (x)(mceval x env)) (cdr exp))))
        (else (error "mceval: Unknown expression type" exp))))

(define (mcapply procedure arguments)
  (cond ((primitive-procedure? procedure)
         (apply-primitive-procedure procedure arguments))
        ((defined-procedure? procedure)
         (eval-sequence
           (proc-body procedure)
           (extend-environment
             (proc-parameters procedure)
             arguments
             (proc-environment procedure))))
        (else (error "mceval: Unknown procedure type" procedure))))

(define (eval-if exp env)
  (if (mceval (cadr exp) env)
      (mceval (caddr exp) env)
      (mceval (cadddr exp) env)))

(define (eval-sequence exps env)
  (cond ((null? (cdr exps)) (mceval (car exps) env))
        (else (mceval (car exps) env)
              (eval-sequence (cdr exps) env))))

(define (eval-assignment exp env)
  (set-variable-value! (cadr exp) (mceval (caddr exp) env) env))

(define (eval-definition exp env)
  (define-variable! 
     (definition-variable exp) 
     (mceval (definition-value exp) env) env))

(define (self-evaluating? exp) 
  (or (eq? exp #t) (eq? exp #f) (number? exp) (string? exp)))

(define (quoted? exp) (tagged-list? exp 'quote))

(define (tagged-list? exp tag)
  (if (pair? exp)
      (eq? (car exp) tag)
      #f))

(define (assignment? exp) (tagged-list? exp 'set!))

(define (definition? exp) (tagged-list? exp 'define))

(define (definition-variable exp)
  (if (symbol? (cadr exp))
      (cadr exp)
      (caadr exp)))

(define (definition-value exp)
  (if (symbol? (cadr exp))
      (caddr exp)
      (make-lambda (cdadr exp)
                   (cddr exp))))

(define (lambda? exp) (tagged-list? exp 'lambda))
(define (lambda-parameters exp) (cadr exp))
(define (lambda-body exp) (cddr exp))
(define (make-lambda parameters body)  (cons 'lambda (cons parameters body)))

(define (if? exp) (tagged-list? exp 'if))
(define (if-predicate exp) (cadr exp))
(define (if-consequent exp) (caddr exp))
(define (if-alternative exp)
  (if (not (null? (cdddr exp)))
      (cadddr exp)
      #f))
(define (make-if predicate consequent alternative)   
   (list 'if predicate consequent alternative))

(define (begin? exp) (tagged-list? exp 'begin))

(define (application? exp) (pair? exp))
(define (operator exp) (car exp))
(define (operands exp) (cdr exp))
(define (no-operands? ops) (null? ops))
(define (car-operand ops) (car ops))
(define (rest-operands ops) (cdr ops))

(define (make-procedure parameters body env)
  (list 'procedure parameters body env))

(define (defined-procedure? p) (tagged-list? p 'procedure))
(define (proc-parameters p) (cadr p))
(define (proc-body p) (caddr p))
(define (proc-environment p) (cadddr p))

(define (enclosing-environment env) (cdr env))
(define (car-frame env) (car env))
(define (make-frame variables values) (cons variables values))
(define (frame-variables frame) (car frame))
(define (frame-values frame) (cdr frame))

(define (add-binding-to-frame! var val frame)
  (set-car! frame (cons var (car frame)))
  (set-cdr! frame (cons val (cdr frame))))

(define (extend-environment vars vals base-env)
  (if (= (length vars) (length vals))
      (cons (make-frame vars vals) base-env)
      (if (< (length vars) (length vals))
          (error "Too many arguments supplied" vars vals)
          (error "Too few arguments supplied" vars vals))))

(define (lookup-variable-value var env)
  (define (env-loop env)
    (define (scan vars vals)
      (cond ((null? vars)
             (env-loop (enclosing-environment env)))
            ((eq? var (car vars))
             (car vals))
            (else (scan (cdr vars) (cdr vals)))))
    (if (eq? env the-empty-environment)
        (error "Unbound variable" var)
        (let ((frame (car-frame env)))
          (scan (frame-variables frame)
                (frame-values frame)))))
  (env-loop env))

(define (set-variable-value! var val env)
  (define (env-loop env)
    (define (scan vars vals)
      (cond ((null? vars)
             (env-loop (enclosing-environment env)))
            ((eq? var (car vars))
             (set-car! vals val))
            (else (scan (cdr vars) (cdr vals)))))
    (if (eq? env the-empty-environment)
        (error "Unbound variable -- SET!" var)
        (let ((frame (car-frame env)))
          (scan (frame-variables frame)
                (frame-values frame)))))
  (env-loop env))

(define (define-variable! var val env)
  (let ((frame (car-frame env)))
    (define (scan vars vals)
      (cond ((null? vars)
             (add-binding-to-frame! var val frame))
            ((eq? var (car vars))
             (set-car! vals val))
            (else (scan (cdr vars) (cdr vals)))))
    (scan (frame-variables frame)
          (frame-values frame))))

(define (primitive-procedure? proc) (tagged-list? proc 'primitive))
(define (primitive-implementation proc) (cadr proc))
(define primitive-procedures
  (list (list 'car car) (list 'cdr cdr) (list 'cons cons)
        (list 'null? null?) (list '+ +) (list '- -) (list '* *)
        (list '/ /) (list '= =)))
(define primitive-proc-names (map car primitive-procedures))
(define primitive-proc-objects
  (map (lambda (p) (list 'primitive (cadr p)))  primitive-procedures))
(define (apply-primitive-procedure proc args) (apply (primitive-implementation proc) args))

(define (scheme)
  (display "Type `exit' to leave MCE\n")
  (schemeloop))

(define (schemeloop)
  (display "\nMCE> ")
  (let ((input (read)))
    (if (equal? input 'exit)
      'done
      (begin (display (mceval input the-global-environment))
             (schemeloop)))))

(define (mcprint object)
  (if (defined-procedure? object)
      (display (list 'defined-procedure
                     (proc-parameters object)
                     (proc-body object)))
      (display object)))

(define (error . args) (begin (display (cons 'ERROR: args)) (newline) #f))

(define the-empty-environment '())

(define (setup-environment)
  (let ((initial-env
         (extend-environment primitive-proc-names
                             primitive-proc-objects
                             the-empty-environment)))
    (define-variable! 'empty '() initial-env)
    initial-env))

(define the-global-environment (setup-environment))

"Metacircular Evaluator Loaded, eval (scheme) to start"